Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Dim strRcFile
Dim strBakFile
Dim strLine
strRcFile = WScript.Arguments.Item(0)
strBakFile = strRcFile & ".bak"
' 現在のファイルのバックアップ
If objFSO.FileExists(strRcFile) Then
 objFSO.CopyFile strRcFile, strBakFile, True
End If

Dim arrValue
Dim arrVersion
Dim intBuildNumber
Set objInFile = objFSO.OpenTextFile(strBakFile)
Set objOutFile = objFSO.CreateTextFile(strRcFile, True)

Do While objInFile.AtEndOfStream <> True
  strLine = objInFile.ReadLine
  If InStr(strLine, "FILEVERSION") <> 0 Or InStr(strLine, "PRODUCTVERSION") Then
  	arrValue = Split(Trim(strLine), " ", -1, vbTextCompare)
  	arrVersion = Split(arrValue(1), ",", -1, vbTextCompare)
  	intBuildNumber = CInt(arrVersion(3)) + 1
  	strLine = " " & arrValue(0) &" " & arrVersion(0) & "," & arrVersion(1) & "," & arrVersion(2) & "," & intBuildNumber
  ElseIf InStr(strLine, "FileVersion") <> 0 Or InStr(strLine, "ProductVersion") Then
  	arrValue = Split(Trim(strLine), " ", -1, vbTextCompare)
  	strLine = "            "
  	intBuildNumber = CInt(Left(arrValue(5), Len(arrValue(5)) - 1)) + 1
  	For lngLoop = 0 To UBound(arrValue)-1
  		strLine = strLine & arrValue(lngLoop) & " "
  	Next
  	strLine = strLine & intBuildNumber & """"
  End If
  objOutFile.WriteLine(strLine)
Loop

objInFile.Close
objOutFile.Close

Set objInFile = Nothing
Set objOutFile = Nothing
Set objFSO = Nothing